Advertisement

The Ultimate Beginner's Guide To AppleScript

by

This is the first post in a new series that revisits some of our readers' favorite posts from the past that still contain awesome and relevant information that you might find useful. This post was originally published on July 7, 2009.

The best part about AppleScript is that you don't have to be a genius programmer to use it. In fact, you don't have to have any programming experience whatsoever. This article will show you how to write an AppleScript for nearly any application using the simple instructions that come hidden within each app's framework. Intrigued? Read on!


What is AppleScript?

AppleScript is a powerful scripting language that comes built-in to OS X. The principal use for AppleScript is the automation of tasks that are normally repetitious and time consuming. For instance, as a freelancer, I hate creating invoices every week for my various clients. To solve this problem I wrote an AppleScript that reads the hours that I log into iCal, creates an invoice in Microsoft Excel based on those hours, and emails the invoices to my clients. All with the click of a button!

applescript
The Main Window

Getting Started: The Tell Block

To create an AppleScript, open the application "Script Editor" located inside the AppleScript folder within the Applications folder. You should see a simple window containing a large text field with a strip of buttons along the top. Inside the text field type the following code:

[applescript]
tell application "Finder"

display dialog "Hello World"

end tell
[/applescript]

AppleScript attempts to use plain English wherever possible to make coding extremely simple. Most commands in AppleScript are located inside a "tell block". It's called a "tell block" because you are "telling" a given application what you want it to do. For instance, the code above is telling the Finder to display a dialog window containing the words "Hello World". After you are finished with a command or string of commands for a given application, you end the block with "end tell".

Always remember to end your tell blocks correctly or the code will not compile!

After you are done entering the code above, click on the "Compile" hammer icon. If your syntax is correct, your code will automatically format and colorize. If you have made an error, Script Editor will highlight the problematic area and give you a message about what it thinks might have gone wrong. Here is a quick reference to the various colors you'll see in your compiled code (found in Script Editor>Preferences).

applescript
Color Guide

After your code has compiled, click on the "Run" button. You should see the following dialog:

applescript
Hello World

Now click the "OK" button and look at the bottom of your Script Editor window. When you run a script, Script Editor tells you what the result was, or what was "returned". In this case it's telling you that the "OK" button was clicked.

applescript
The OK Return

Declaring Variables

Variables are essentially the same in every programming language. They provide an easy way to access and manipulate lots of information in a compact snippet of code. Creating or "declaring" variables is different for every language. In AppleScript you declare variables as follows:

[applescript]
set theString to "Hello World"

tell application "Finder"

display dialog theString

end tell
[/applescript]

There are several things to note about the previous example. First, notice that variables are declared using the "set" and "to" commands. By doing this you are setting your variable name, in this case "theString", to equal something, in this case the text "Hello World". Many programming languages require that you state the type of variable you want in the declaration (integer, floating point, text, etc.). AppleScript however, is intelligent enough to work with your variables without any instruction about the format.

Also notice how I typed my variable name. You can't have spaces in a variable name so it's good practice to use camel case (theString) or the underscore method (the_string). It doesn't really matter which method you choose, just make sure you're consistent throughout your code. It's also a good idea to give all your variables meaningful names. When you are looking another programmer's code, it can be annoying to see variable names like "myVariable" that don't give any indication as to what they are or what they will be used for.

Finally, notice that now that I've placed the text "Hello World" inside a variable, I can call that variable again and again throughout my code. Then if I later decide to change the text "Hello World" to "Good Morning Dave", I only have to change the text on the line where I declared the variable.


Working with Variables

You can do all kinds of crazy things with variables, but since this is only meant to be a brief introduction to AppleScript, I'll just show you a few. Type in the following code:

[applescript]
--Integer Variables
set theFirstNumber to 3
set the theSecondNumber to 2

--Variable Operations
set theAnswer to (theFirstNumber + theSecondNumber)
set theAnswer to (theAnswer + 1)

--String Variables
set theString to "3+2+1="

--Display Dialog
tell application "Finder"

display dialog theString & theAnswer

end tell
[/applescript]

You can compile your code quickly by pressing the "enter" key (not the return key). This is located on the ten key number pad on desktop computers and next to the "Command" key to the right of the space bar on laptops.

As your script becomes more complex, a bit of organization is in order. By typing two dashes "--" before a line of text, you can insert a comment. Use comments to separate and describe your sections of code for easy navigation. In this example I've created a string variable (text only) and a few integer variables. Notice that you can perform mathematical operations on variables. Here I've set "theFirstNumber" to equal three and "theSecondNumber" to equal two and then added them together in "theAnswer".

Also notice that you can change a variable after it is declared. Immediately after setting "theAnswer" to the sum of "theFirstNumber" and "theSecondNumber" (resulting in 5), I changed the value of "theAnswer" by adding one to it (resulting in 6). If you run this script you should see the following result:

applescript
Some Basic Math

Again, this only scratches the surface of the kinds of operations you can perform on variables. For now you should just understand that a variable isn't static. Much of the power of behind any programming language is the ability to manipulate variables to perform a wide variety of tasks.


The Key to it All: AppleScript Dictionaries

Though AppleScript itself has a wide range of commands that can be applied to any program or item in OS X, the developers of each application are tasked with adding full AppleScript support to their apps. What this means is that developers must write simple manuals for how to communicate with their applications through AppleScript. These manuals are called "Dictionaries". To view a dictionary, go to File>Open Dictionary in Script Editor. Scroll down the list of applications, click on Mail and hit "OK". You should see the following window:

applescript
The Mail Dictionary

The column on the left contains the available "Suites" of commands and items. When you click on a suite, you'll see everything contained in the suite displayed below. You can narrow this preview by clicking in the second column, then again in the third. Suites contain commands (C with a circle) and classes (C with a square), classes contain properties (P) and elements (E). To understand how all this works, let's use this dictionary to create a script.


Step 1: Create an Algorithm for Our Script

First we need an algorithm, which is a fancy way to say that we need write down exactly what our script will do. We want to create a script to compose and send an email. We'll want to use variables to make it easy to change the message itself as well as who the message is sent to. As we write our algorithm, we need to keep in mind the way AppleScript works. Here are the steps I came up with:

  1. Create variables for the recipient, the recipient's email address, the subject of the email, and the text for the body of the email.
  2. Create a variable that holds our new message along with its various properties
  3. Create the new message
  4. Send the new message

Step 2: Create Some Variables

We already know how to create variables holding text so we don't even need the dictionary for step one. Here's what the code looks like:

[applescript]
--Variables
set recipientName to "John Doe"
set recipientAddress to "nobody@nowhere.com"
set theSubject to "AppleScript Automated Email"
set theContent to "This email was created and sent using AppleScript!"
[/applescript]

As you can see, we've just put placeholder text into the variables for the name and email address of the recipient as well as the subject and content of our message. You can change these to anything you'd like. Be sure to put your own email address in the recipientAddress variable so you can ensure that the the script is working properly when you receive the email.


Step 3: Create the Message Variable with the Mail Dictionary

Since we have no idea how to tell Mail to create a new message, this is where we need to refer to the AppleScript dictionary. If you click on "Standard Suite" you'll see several common commands that come standard in AppleScript. Knowing that we want to "create" a new message, we just scroll through the options and find something equivalent. You'll see there is no "create" command but about half way down there is a "make" command. That sounds perfect, so we now know to tell AppleScript we want to "make" something.

Next click on the "Mail" suite. We've already got our command (make) so scroll down past the commands (verbs) until you see the classes (nouns). The first class we come across is "outgoing message", which is great because that's exactly what we want! Now click on the "outgoing message" class and look at the available properties down below.

We need to plug in our variables for the recipient's name, the recipient's email address, the subject, and the contents of the message. In the list of properties there isn't anything about the recipient but there are properties for subject and content. We now know the proper syntax to refer to these properties. Notice that the dictionary gives you the format to define the properties. For instance for the subject, we'll type the word "subject" followed by a colon followed by the text of the subject.

applescript
Subject Content

Also in this suite you'll find a "send" command, which we can use to send the message by simply typing "send". We still need to know the proper syntax for the recipient's name and email address. Since it's not in this suite, click on the "Message" suite. About halfway down the list of classes we find "recipient". Click on the recipient class and we see that once again, we can use plain English to refer to the properties of the recipient. We'll simply type "name" and "address".

You can use the search feature to hunt down properties, classes, elements and commands quickly.

Now we are ready to create our message variable using the syntax we've just learned. Here's what the code looks like:

[applescript]
--Variables
set recipientName to "John Doe"
set recipientAddress to "nobody@nowhere.com"
set theSubject to "AppleScript Automated Email"
set theContent to "This email was created and sent using AppleScript!"

--Mail Tell Block
tell application "Mail"

--Create the message
set theMessage to make new outgoing message with properties {subject:theSubject, content:theContent, visible:true}

end tell
[/applescript]

Notice I've created a tell block to enclose all the commands to the Mail application. Then I set a variable (theMessage) to "make" a new "outgoing message" with the properties discussed above. Also notice that sets of properties are always contained in brackets { }.


Step 4: Set the Recipient and Send the Message

Now that we've created our message variable, we need to call that variable and create a new message with the properties of theMessage. We also need to set the recipients and send the message. To do this, we'll use a tell block on our variable. Here's our finished script.

[applescript]
--Variables
set recipientName to "John Doe"
set recipientAddress to "nobody@nowhere.com"
set theSubject to "AppleScript Automated Email"
set theContent to "This email was created and sent using AppleScript!"

--Mail Tell Block
tell application "Mail"

--Create the message
set theMessage to make new outgoing message with properties {subject:theSubject, content:theContent, visible:true}

--Set a recipient
tell theMessage
make new to recipient with properties {name:recipientName, address:recipientAddress}

--Send the Message
send

end tell
end tell
[/applescript]

First, we created a new copy of theMessage (which inherits all the properties we've put into it) and set it "to recipient with properties". This tells Mail that we want to add a recipient with the following properties. Here we just used the syntax we learned before and the variables for the name and address of the recipient.

Finally, we invoked the "send" command to send our message. Notice that we have two tell blocks to close this time. Once you've compiled your code and fixed any errors hit the "Run". Mail should automatically create and send the message. Tadaah! Check your sent folder to make sure everything worked.

applescript
Mail Message

Congratulations, you've created your first AppleScript! You can save it as a simple script that you can come back and edit or as an application that runs automatically when you open it.


Conclusion: Keep Learning

I hope this beginner's guide has you thinking about all kinds of processes and tasks you'd like to automate. The syntax I've shown you along with the AppleScript Dictionaries will get you a long way. However, if you're really interested in implementing AppleScript in a number of useful ways, you've got more reading to do. Apple provides lots of information all about AppleScript on their website. Here's a good place to start.

Another website I've picked up a great deal from is T&B. It offers some really in-depth explanations and tutorials for you to follow (a little dated, but thorough and free). Please feel welcome to leave a comment and let us know if you found this tutorial helpful! What other AppleScript tips would you like to see covered in the future?

Advertisement